Gnuplot: ajustando curvas

MSPC - Informações Técnicas

Gnuplot: ajustando curvas

Índice do grupo | Página anterior | Próxima página |

Para quem não conhece, Gnuplot é um eficiente programa para traçado de curvas de funções matemáticas contínuas ou discretas. A interface com o usuário pode não parecer amigável porque funciona pela linha de comando, mas os recursos de que dispõe compensam esse aspecto. É de livre distribuição e há versões para quase todos os sistemas operacionais. Mais informações no site do programa (em inglês).

Esta página não tem o propósito de dar informações sobre o uso do programa, que são bastante extensas e podem ser vistas no site mencionado e em outros. Ela mostra apenas o recurso, muitas vezes bastante útil, do ajuste de curvas (curve fitting, em inglês).

O assunto é dado com um exemplo prático: a tabela abaixo contém os índices de inflação no Brasil, acumulados de junho de 1996 a dezembro de 2007.

Por questão de espaço, os dados estão divididos em 5 colunas. Em cada coluna, os números à esquerda são os meses (1 equivale a jun/1996) e os da direita são os índices de inflação acumulados segundo INPC do IBGE (base 1.0000 em junho de 1996).

Fig 01

Para uso com o programa Gnuplot, esses dados devem estar em um arquivo de texto puro, que aqui será denominado gnu_10.dat (naturalmente, em seqüência de apenas duas colunas, meses e índices separados por tabulação. Não podem ser as cinco colunas da tabela anterior. Se os dados estiverem em uma planilha de cálculo, o arquivo pode ser obtido pelas simples operações de copiar e colar para um editor de texto puro, como Bloco de Notas do Windows ou KWrite do Linux. Na planilha, devem estar em colunas vizinhas. Usar ponto como separador decimal).

O gráfico da Figura 01 foi obtido com o script abaixo.

set terminal svg
set output "gnu_10.svg"

set decimalsign ","

set xtics nomirror
set ytics nomirror
set border 3

set size 0.76,0.76
set size ratio 0.5
set yrange [1.0:2.5]

set xrange [1.0:150]

set xtics rotate ("06/96" 1, "06/97" 13, "06/98" 25, "06/99" 37, 
"06/00" 49, "06/01" 61, "06/02" 73, "06/03" 85, "06/04" 97, "06/05" 109, 
"06/06" 121, "06/07" 133, "06/08" 145)

set grid

set label "Mês / Ano" at 144, 1.1 right
set label "Índice acumulado" at 3,2.5 left

plot 'gnu_10.dat' using 1:2 notitle with lines lt 1 lc rgb 'blue'

pause -1

O objetivo agora é determinar uma função polinomial que represente uma aproximação da curva anterior. Seja a função:

y = a (x − 1)⁵ + b (x − 1)⁴ + c (x − 1)³ + d (x − 1)² + e (x − 1) + 1.

Foi escolhida dessa forma porque, para x = 1, o valor y é exatamente 1, em conformidade com os dados da tabela anterior. Naturalmente, a aproximação melhora com maior ordem do polinômio. Isso pode ser feito por tentativas. Neste caso, escolheu-se 5. E o script para determinar os coeficientes a, b, c, d é dado a seguir.

f(x) = a * (x - 1)**5 + b * (x - 1)**4 + c * (x - 1)**3 + d * (x - 1)**2 + e * (x - 1) + 1

fit f(x) 'gnu_10.dat' using 1:2 via a,b,c,d,e

O resultado desse script é dado abaixo.

Final set of parameters            Asymptotic Standard Error
=======================            ==========================

a               = 2.94234e-10      +/- 2.773e-11    (9.424%)
b               = -1.09622e-07     +/- 9.262e-09    (8.449%)
c               = 1.36743e-05      +/- 1.091e-06    (7.977%)
d               = -0.000606089     +/- 5.296e-05    (8.737%)
e               = 0.0125261        +/- 0.0008876    (7.086%)


correlation matrix of the fit parameters:

               a      b      c      d      e
a               1.000
b              -0.995  1.000
c               0.975 -0.992  1.000
d              -0.927  0.958 -0.986  1.000
e               0.821 -0.866  0.917 -0.968  1.000

Fig 02

Uma vez determinados os coeficientes a, b, c , d e e, eles podem ser substituídos na fórmula anterior, que representará uma função contínua aproximada para os índices de inflação conforme tabela anterior.

O gráfico da Figura 02 é uma comparação da função contínua com a curva discreta anterior. É possível notar uma boa aproximação, inclusive nos pontos extremos.

O script para gerar esse gráfico é similar ao anterior, com a inclusão da curva para a função contínua.

set terminal svg
set output "gnu_16.svg"

a = 2.94232e-10
b = -1.09622e-07
c = 1.36743e-05
d = -0.000606089
e = 0.0125261

f(x) = a * (x - 1)**5 + b * (x - 1)**4 + c * (x - 1)**3 + d * (x - 1)**2 + e * (x - 1) + 1

set decimalsign ","

set xtics nomirror
set ytics nomirror
set border 3

set size 0.76,0.76
set size ratio 0.5
set yrange [1.0:2.5]

set xrange [1.0:139]

set xtics rotate ("06/96" 1, "06/97" 13, "06/98" 25, "06/99" 37,
"06/00" 49, "06/01" 61, "06/02" 73, "06/03" 85, "06/04" 97, "06/05" 109,
"06/06" 121, "06/07" 133, "06/08" 145)

set grid

set label "Mês / Ano" at 144, 1.1 right
set label "Índice acumulado" at 3,2.5 left

plot f(x), 'gnu_10.dat' using 1:2 notitle with lines lt 1 lc rgb 'blue'

Topo | Página anterior | Próxima página | Última revisão ou atualização: Dez/2009